<b>让sqlserver恢复到某个时间点</b>[MSSQL防范]

假如要让sqlserver恢复到某个时间点的状况,能否可行呢?答案是必定的,下面就教您这种sqlserver恢复的办法,供您参考,但愿在您学习sqlserver恢复的历程中能起到些许作用.

--成立测试数据库   
CREATE DATABASE Db   
GO   
 
--对数据库举行备份   
BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT   
GO   
 
--成立测试表   
CREATE TABLE Db.dbo.TB_test(ID int)   
 
--延时1秒钟,再举行背面的操作(这是由于SQL Server的时间精度最大为百分之三秒,不延时的话,大概会招致复原到时间点的操作失利)   
WAITFOR DELAY '00:00:01'   
GO   
 
--假定我们目前误操作删除了 Db.dbo.TB_test 这个表   
DROP TABLE Db.dbo.TB_test   
 
--保存删除表的时间   
SELECT dt=GETDATE() INTO #   
GO   
 
--在删除操作后,发现不该该删除表 Db.dbo.TB_test   
 
--下面演示了若何恢复这个误删除的表 Db.dbo.TB_test   
 
--首先,备份事件日记(利用事件日记才能复原到指定的时间点)   
BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT   
GO   
 
--接下来,我们要先复原完好备份(复原日记必须在复原完好备份的底子上举行)   
RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY   
GO   
 
--将事件日记复原到删除操作前（这里的时间对应上面的删除时间,并比删除时间略早   
DECLARE @dt datetime   
SELECT @dt=DATEADD(ms,-20,dt) FROM #  --获得比表被删除的时间略早的时间   
RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt   
GO   
 
--查询一下,看表能否恢复   
SELECT * FROM Db.dbo.TB_test   
 
/*--后果:   
ID             
-----------    
 
（所影响的行数为 0 行）   
--*/   
 
--测试成功   
GO   
 
--最后删除我们做的测试环境   
DROP DATABASE Db   
DROP TABLE #